Oblate Spheroid

Author

Eric W. Weisstein
February 8, 2009

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/OblateSpheroid.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/OblateSpheroid.html.

©2009 Wolfram Research, Inc. except for portions noted otherwise

Initialization

Graphic

Show[Graphics3D[Spheroid[1.2,1]],Boxed->False]

Parametric

x[λ_,δ_]:=a Cos[λ]Cos[δ]
y[λ_,δ_]:=a Sin[λ]Cos[δ]
z[λ_,δ_]:=c Sin[δ]

((#)/((a^2)(c^2)))&/@GroebnerBasis[{x-a cosu sinv,y-a sinu sinv,z-c cosv,sinu^2+cosu^2-1,sinv^2+cosv^2-1},{x,y,z},{sinu,cosu,sinv,cosv},MonomialOrder->EliminationOrder][[1]]//Simplify

Fundamental Forms

FirstFundamentalForm[{a Cos[u]Sin[v],a Sin[u]Sin[v],c Cos[v]},{u,v}]//Simplify//TraditionalForm

Simplify[SecondFundamentalForm[{a Cos[u]Sin[v],a Sin[u]Sin[v],c Cos[v]},{u,v}],a>0]//TraditionalForm

Volume

Integrate[Boole[(((x^2)+(y^2))/(a^2))+((z^2)/(c^2))<1],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞}]//Timing

Integrate[Boole[(((x^2)+(y^2))/(a^2))+((z^2)/(c^2))<1],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->0<c<a]//Timing

Centroid

Integrate[x Boole[(((x^2)+(y^2))/(a^2))+((z^2)/(c^2))<1],{x,0,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->0<c<a]//Timing

(((1/4) (a^3) c π)/((4/3) (a^2) c π))

Integrate[z Boole[(((x^2)+(y^2))/(a^2))+((z^2)/(c^2))<1],{x,-∞,∞},{y,-∞,∞},{z,0,∞},Assumptions->0<c<a]//Timing

(((1/4) (a^2) (c^2) π)/((4/3) (a^2) c π))

Surface Area

Various Forms

forms={2 π (a^2+((a (c^2) )/(Sqrt[(a^2)-(c^2)]))Log[((a+(Sqrt[(a^2)-(c^2)]))/c)]),π (2a^2+((a (c^2) )/(Sqrt[(a^2)-(c^2)]))Log[((a+Sqrt[a^2-c^2])/(a-Sqrt[a^2-c^2]))]),With[{e=Sqrt[a^2-c^2]/a},2π a^2+π ((c^2)/e)Log[((1+e)/(1-e))]],2π (a^2)-((2π I a (c^2))/(Sqrt[(a^2)-(c^2)]))ArcCos[(a/c)]};

forms/.{a->1,c->.3}//Chop

Append[forms,4.π (a^2)]/.{a->1,c->.999999}//Chop

Print[Timing[Limit[#,c->a,Direction->1]]]&/@forms

Limit[2π (a^2)-((2π I a (c^2))/(Sqrt[(a^2)-(c^2)]))ArcCos[(a/c)],c->a,Direction->1]

Simplify[%,a>0]

Limit[2π (a^2)-((2π I a (c^2))/(Sqrt[(a^2)-(c^2)]))ArcCos[(a/c)],c->a,Assumptions->a>0,Direction->1]

Radial Integration

r[z_]:=a Sqrt[1-((z/c))^2]

FullSimplify[r[z]Sqrt[1+r'[z]^2],0<c<a]

Sqrt[FullSimplify[(1-((z^2)/(c^2)))(1+(((a^2) (z^2))/((c^4)-(c^2) (z^2))))] ]

s=FullSimplify[2Pi a Integrate[Sqrt[1+(a-c)(a+c)z^2/c^4],{z,-c,c},Assumptions->0<c<a]]

Together/@FullSimplify[TrigToExp[s],0<c<a]

2 π (a^2+((a (c^2) )/(Sqrt[(a^2)-(c^2)]))Log[((a+(Sqrt[(a^2)-(c^2)]))/c)])

id=Log[((a+Sqrt[a^2-c^2])/c)]-1/2 Log[((a+Sqrt[a^2-c^2])/(a-Sqrt[a^2-c^2]))];

FullSimplify[id,0<c<a]

π (2a^2+((a (c^2) )/(Sqrt[(a^2)-(c^2)]))Log[((a+Sqrt[a^2-c^2])/(a-Sqrt[a^2-c^2]))])

OblateSpheroidSurfaceArea0[a_,c_]:=
π (2a^2+((a (c^2) )/(Sqrt[(a^2)-(c^2)]))Log[((a+Sqrt[a^2-c^2])/(a-Sqrt[a^2-c^2]))])

OblateSpheroidSurfaceArea0[3,1]//N

OblateSpheroidSurfaceArea1[a_,c_]:=Module[
{e=Sqrt[a^2-c^2]/a},
2π a^2+π ((c^2)/e)Log[((1+e)/(1-e))]
]

OblateSpheroidSurfaceArea1[3,1]//N

Via First Fundamental Form

FullSimplify[(Sqrt[ℰ 𝒢-(ℱ^2)]),0<c<a&&0<u<2π&&0<v<π]

With[{a=3,c=1},2π NIntegrate[((a (Sqrt[(a^2)+(c^2)+(a-c) (a+c) Cos[2 v]]) Sin[v])/(Sqrt[2])),{v,0,π}]]

2π Integrate[((a (Sqrt[(a^2)+(c^2)+(a-c) (a+c) Cos[2 v]]) Sin[v])/(Sqrt[2])),{v,0,π},Assumptions->0<c<a]//Timing

s=FullSimplify[((2 a π ((a^3)-a (c^2)-I (c^2) (Sqrt[(a^2)-(c^2)]) ArcCos[(a/c)]))/((a^2)-(c^2))),0<c<a]

With[{a=3,c=1},2 a π (a-((I (c^2) ArcCos[(a/c)])/(Sqrt[(a-c) (a+c)])))]//N

OblateSpheroidSurfaceArea2[a_,c_]:=2 a π (a-((I (c^2) ArcCos[(a/c)])/(Sqrt[(a-c) (a+c)])))

OblateSpheroidSurfaceArea2[3,1]//N

FullSimplify[TrigToExp[s],0<c<a]

OblateSpheroidSurfaceArea3[a_,c_]:=2 a π (a+(((c^2) Log[((a+(Sqrt[(a^2)-(c^2)]))/c)])/(Sqrt[(a-c) (a+c)])))

OblateSpheroidSurfaceArea3[3,1]//N

Ellipticity

Solve[{ϵ==(a-c)/a,e^2==1-c^2/a^2},ϵ,{a,c}]

Map[Factor,Solve[{ϵ==(a-c)/a,e^2==1-c^2/a^2},e,{a,c}],{-4}]

Distances

Distance from Center

r=FullSimplify[Sqrt[Plus@@(#[λ,δ]^2&/@{x,y,z})]]

r2=PowerExpand[FullSimplify[r/.c->a Sqrt[1-e^2]]]

Expand[TrigExpand[2-(e^2)+(e^2) Cos[2 δ]] /. Cos[δ]->Sqrt[1-Sin[δ]^2]]

Simplify[a Sqrt[2-2 (e^2) ((Sin[δ])^2)]/Sqrt[2]]

PowerExpand[a (Sqrt[1-(e^2) ((Sin[δ])^2)]) /. {e->Sqrt[1-c^2/a^2],δ->#}&/@{0,-Pi/2,Pi/2}]

Distance from Rotation Axis

r=FullSimplify[Sqrt[Plus@@(#[λ,δ]^2&/@{x,y})]]

PowerExpand[%]