Eight Surface

Author

Eric W. Weisstein
July 11, 2013

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/EightSurface.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/EightSurface.html.

©2013 Wolfram Research, Inc. except for portions noted otherwise

Initialization

EightSurface[u_,v_]:=a{Cos[u]Sin[2v],Sin[u]Sin[2v],Sin[v]}

Surface

eight=ParametricPlot3D[Evaluate[EightSurface[u,v]/.a->1],{u,0,2Pi},{v,-π/2,π/2},Boxed->False,Axes->False]

LiveGraphics3D

<<Utilities`LiveGraphics3D`

WriteLiveForm["eight.m",eight]

Cross Section

Plot[Table[((2 (Sqrt[(a^2) (z^2)-(z^4)]))/a),{a,.5,2,.5}],{z,-2,2}]

Equations

eqns=Join[Thread[{x,y,z}==TrigExpand/@EightSurface[u,v]],Sin[#]^2+Cos[#]^2==1&/@{u,v}]

eqn=Factor/@GroebnerBasis[eqns,{x,y,z},{Cos[u],Sin[u],Cos[v],Sin[v]},MonomialOrder->EliminationOrder]

Solve[(a^2)(r^2)-4 (a^2) (z^2)+4 (z^4)==0,r]

FullSimplify[eqn]

eqn=4 (z^4)+(a^2) ((x^2)+(y^2)-4 (z^2));

Simplify[Solve[4 (z2^2)+(a^2) ((x^2)+(y^2)-4 z2)==0,z2],a>0]

With[{r=1},RegionPlot3D[Evaluate[eqn[[1]]/.a->1]<0,{x,-r,r},{y,-r,r},{z,-r,r}]]

With[{r=1},ContourPlot3D[Evaluate[eqn[[1]]/.a->1]==0,{x,-r,r},{y,-r,r},{z,-r,r}]]

Properties

Curvatures[EightSurface[u,v],{u,v},Refine[FullSimplify[#,a>0&&-Pi/2<v<π/2],a>0]&]

FullSimplify[PrincipalCurvatures[EightSurface[u,v],{u,v}],a>0&&0<u<2π&&-π/2<v<π/2]

FullSimplify[GaussianCurvature[eqn,{x,y,z}]]

Surface Area

Numeric

(1/(Sqrt[2]))NIntegrate[(Sqrt[(5+Cos[2 v]+4 Cos[4 v]) ((Sin[2 v])^2)]),{u,0,2Pi},{v,-π/2,π/2}]

Area Element

Refine[FullSimplify[AreaElement[EightSurface[u,v],{u,v}],a>0],a>0]

(i=((a^2 )/(Sqrt[2]))Integrate[(Sqrt[(5+Cos[2 v]+4 Cos[4 v]) ((Sin[2 v])^2)]),{u,0,2Pi},{v,-π/2,π/2}])//Timing

FullSimplify[(1/256) (a^2) π (480+272 (Sqrt[5])+62 ArcSinh[(17/(Sqrt[31]))]+31 Log[31])]

N[%]

FullSimplify[TrigToExp[(1/256)  π (480+272 (Sqrt[5])+62 ArcSinh[(17/(Sqrt[31]))]+31 Log[31])]]

(1/128) π (240+136 (Sqrt[5])+31 Log[17+8 (Sqrt[5])])//N

Surface of Rotation

FullSimplify[((2 (Sqrt[(a^2) (z^2)-(z^4)]))/a)Sqrt[1+((D[((2 (Sqrt[(a^2) (z^2)-(z^4)]))/a),z])^2)],a>0]

2π Integrate[((2 (Sqrt[(a-z) (z^2) (a+z)]) (Sqrt[1-((16 (z^2))/(a^2))+((4 (a^2))/((a^2)-(z^2)))]))/a),{z,-a,a},Assumptions->a>0]

FullSimplify[%]

N[%]

Volume

Numeric

NIntegrate[Boole[4 (z^4)+(a^2) ((x^2)+(y^2)-4 (z^2))<0/.a->1],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞}]

Solid of Rotation

(4/(a^2))π Integrate[(a^2) (z^2)-(z^4),{z,-a,a}]//Simplify

N[%/.a->1]

Cartesian

(i=Integrate[Boole[4 (z^4)+(a^2) ((x^2)+(y^2)-4 (z^2))<0],{x,-∞,∞},{y,-∞,∞},{z,-∞,∞},Assumptions->a>0])//Timing

...crash (on prism)...

Cylindrical

FullSimplify[4 (z^4)+(a^2) ((x^2)+(y^2)-4 (z^2))/.{x->r Cos[θ],y->r Sin[θ]},r>0&&0<θ<2π]

Integrate[Boole[4 (z^4)+(a^2) ((r^2)-4 (z^2))<0]r,{r,0,∞},{θ,0,2π},{z,-∞,∞},Assumptions->a>0]//Timing

Centroid

Integrate[{r Cos[θ],r Sin[θ],z}Boole[4 (z^4)+(a^2) ((r^2)-4 (z^2))<0]r,{r,0,∞},{θ,0,2π},{z,-∞,∞},Assumptions->a>0]//Timing

Inertia Tensor

(M/((16 (a^3) π)/15))Integrate[InertiaTensor[{r,θ,z},"CoordinateSystem"->"Cylindrical"]Boole[4 (z^4)+(a^2) ((r^2)-4 (z^2))<0]r,{θ,0,2π},{z,-∞,∞},{r,0,∞},Assumptions->a>0]//Timing

Metric Properties

Metric Tensor

MetricTensor[EightSurface[u,v],{u,v}]//FullSimplify

Christoffel Symbol of the Second Kind

FullSimplify[ChristoffelSymbols[EightSurface[u,v],{u,v}],a>0]

Vector Properties

eqn=a {Cos[u] Sin[2 v],Sin[u] Sin[2 v],Sin[v]};
rules={Abs[x_]^(n_/;Mod[n,2]==0):>x^n};
assum=a>0&&0<u<2π&&-π/2<v<π/2;

Vector Length

Assuming[assum,FullSimplify[Norm[eqn]/.rules]]

Normal Vector

Assuming[assum,FullSimplify[NormalVector[eqn,{u,v}]/.rules]]