Gudermannian

Author

Eric W. Weisstein
September 13, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/Gudermannian.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Gudermannian.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Notation

Gudermannian[x]//TraditionalForm

Plots

<<Utilities`Plot`

Real Axis

Plot[Gudermannian[x],{x,-10,10},
PlotStyle->Red,AxesLabel->TraditionalForm/@{x,Gudermannian[x]}]

Plot[InverseGudermannian[x],{x,-10,10},
PlotStyle->Red,AxesLabel->TraditionalForm/@{x,InverseGudermannian[x]},PlotRange->10{-1,1},PlotPoints->100]

Complex Plane

ComplexPlot3D[Gudermannian[z],{z,-5,5},PlotPoints->100,ComplexPlotLabel->HoldForm[Gudermannian[z]]]//Timing

ComplexContourPlot[Gudermannian[z],{z,-5,5},ComplexPlotLabel->HoldForm[Gudermannian[z]]]//Timing

ComplexPlot3D[InverseGudermannian[z],{z,-π/2-5I,π/2+5I},PlotPoints->100,ComplexPlotLabel->HoldForm[InverseGudermannian[z]]]//Timing

ComplexContourPlot[InverseGudermannian[z],{z,-π/2-5I,π/2+5I},PlotPoints->100,ComplexPlotLabel->HoldForm[InverseGudermannian[z]]]//Timing

Identities

FunctionExpand[Gudermannian[z]]//TraditionalForm

2 (tan^(-1))(tanh((x/2)))

Integrate[1/Cosh[t],{t,0,x},Assumptions->x>0]

FullSimplify[2ArcTan[Tanh[x/2]],x∈Reals]

(tan^(-1))(sinh(x))

FullSimplify[ArcTan[Sinh[x]]]

FullSimplify[ArcTan[Sinh[x]],x∈Reals]

2 (tan^(-1))((e^x))-(π/2)

FullSimplify[2ArcTan[Exp[x]]-Pi/2]

tanh((x/2))==tan(((gd(x))/2))

FullSimplify[Tan[(1/2)Gudermannian[x]]]

Subtract@@{Tanh[(1/2)x],Tan[(1/2)Gudermannian[x]]}//FullSimplify

gd(i x)==i (gd^(-1))(x)

FullSimplify[Gudermannian[I x]-I InverseGudermannian[x],x>0]

FunctionExpand[%]//FullSimplify

Derivative and Integral

Derivative

D[Gudermannian[x],x]

Integrate[D[Gudermannian[x],x],x]

FullSimplify[%]

Integral

Integrate[Gudermannian[x],x]

FullSimplify[%]

D[Integrate[Gudermannian[x],x],x]

FullSimplify[%]

Series

ser=Series[Gudermannian[x],{x,0,15}]

Through[{Numerator,Denominator}[DeleteCases[CoefficientList[ser,x],0]]]

SeriesCoefficient[Gudermannian[x],{x,0,n}]//Timing

SeriesCoefficient[Gudermannian[x]//FunctionExpand,{x,0,n}]//Timing

SeriesCoefficient[Log[Tan[x]+Sec[x]],{x,0,n}]//Timing

SeriesCoefficient[ArcTan[Sinh[x]],{x,0,n}]//Timing

Trigonometric and Hyperbolic

FullSimplify[Subtract@@{#[[1]][Gudermannian[z]],#[[2]][z]}]&/@{{Sin,Tanh},{Cos,Sech},{Tan,Sinh},{Cot,Csch},{Sec,Cosh},{Csc,Coth}}

Exponential

FullSimplify/@{Sec[Gudermannian[x]]+Tan[Gudermannian[x]],Tan[(1/4)π+(1/2)Gudermannian[x]],((1+Sin[Gudermannian[x]])/(Cos[Gudermannian[x]]))}

Complex

tan(a)==((sinh(x))/(cos(y)))

diff=With[{a=Re[Gudermannian[x +I y]],b=Im[Gudermannian[x +I y]]},FullSimplify[Subtract@@{Tan[a],((Sinh[x])/(Cos[y]))},(x|y)∈Reals]
]

tanh(b)==((sin(y))/(cosh(x)))

diff=With[{a=Re[Gudermannian[x +I y]],b=Im[Gudermannian[x +I y]]},FullSimplify[Subtract@@{Tanh[b],((Sin[y])/(Cosh[x]))},(x|y)∈Reals]
]

tanh(x)==((sin(a))/(cosh(b)))

diff=With[{a=Re[Gudermannian[x +I y]],b=Im[Gudermannian[x +I y]]},FullSimplify[Subtract@@{Tanh[x],((Sin[a])/(Cosh[b]))},(x|y)∈Reals]
]

tan(y)==((sinh(b))/(cos(a)))

diff=With[{a=Re[Gudermannian[x +I y]],b=Im[Gudermannian[x +I y]]},FullSimplify[Subtract@@{Tan[y],((Sinh[b])/(Cos[a]))},(x|y)∈Reals]
]

tanh(x) tan(y)==tan(a) tanh(b)

diff=With[{a=Re[Gudermannian[x +I y]],b=Im[Gudermannian[x +I y]]},FullSimplify[Subtract@@{Tanh[x]Tan[y],Tan[a]Tanh[b]},(x|y)∈Reals]
]