Theodorus Spiral

Author

Eric W. Weisstein
January 9, 2017

This notebook downloaded from http://mathworld.wolfram.com/notebooks/PlaneGeometry/TheodorusSpiral.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/TheodorusSpiral.html.

©2017 Wolfram Research, Inc. except for portions noted otherwise

Code

FullSimplify[Subtract@@{π/2-ArcTan[x],ArcCot[x]},x>0]

TheodorusSpiral[n_]:=AnglePath[{1,0},Table[{1,ArcCot[Sqrt[k-1]]},{k,n}]]

Graphics

spiral=TheodorusSpiral[16];

square[{o_,x_,y_},s_:.2]:=Line[o+s#&/@{x,x+y,y}]

Graphics[{
Point[{0,0}],
{
Thin,
Line[{{0,0},#}&/@spiral],
square[{#1,-Normalize[#1],Normalize[#2-#1]},.15]&@@@Partition[spiral,2,1]
},
MapIndexed[Text[#2[[1]]/.n_Integer:>Sqrt[HoldForm[n]],#1/2,Background->White]&,spiral],
Red,Line[spiral]
}]

Interpolant

Product[((1+(I/(Sqrt[k])))/(1+(I/(Sqrt[k-1+n])))),{k,∞}]

ispiral=ReIm/@Table[Product[((1+(I/(Sqrt[k])))/(1+(I/(Sqrt[k-1+n])))),{k,(10^6)}]//N,{n,4}]

Graphics[{
Point[{0,0}],
{
Thin,Red,Line[{{0,0},#}&/@Take[spiral,4]],
Thick,Yellow,Line[{{0,0},#}&/@ispiral]
}
}]