Chebyshev Functions

Author

Eric W. Weisstein
January 17, 2009

This notebook downloaded from http://mathworld.wolfram.com/notebooks/NumberTheoreticFunctions/ChebyshevFunctions.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/ChebyshevFunctions.html.

©2009 Wolfram Research, Inc. except for portions noted otherwise

Code

Primorial[0]:=1
Primorial[1]:=2
Primorial[n_]:=Primorial[n]=Prime[n]Primorial[n-1]

ChebyshevPsi[x_]:=Log[LCM@@Range[x]]
ChebyshevTheta[n_]:=Log[Primorial[PrimePi[n]]]

θ (x)

Table[ChebyshevTheta[n],{n,2,10}]//Simplify

MakeBoxes[InlineFraction[n_,d_],TraditionalForm]:=RowBox[{RowBox[{MakeBoxes[n,TraditionalForm],"/",MakeBoxes[d,TraditionalForm]}]}]

Show[GraphicsArray[{ListPlot[Table[ChebyshevTheta[n],{n,2,100}],
Joined->True,AxesLabel->{x,θ[x]},PlotStyle->Red],
ListPlot[Table[n/ChebyshevTheta[n]//N,{n,2,10^5}],
Joined->True,PlotRange->{{1,10^5},{.99,1.02}},
AxesOrigin->{0,.98999},
Epilog->{Dashing[{.04}],Blue,Line[{{0,1},{10^5,1}}]},
Ticks->{Transpose[Table[Range[0,10^5,25000],{2}]],
{#,NumberForm[#,{4,2},NumberPadding->{"","0"}]}&@@@Transpose[Table[Range[.99,1.02,.01],{2}]]},AxesLabel->{x,InlineFraction[x,θ[x]]},
PlotStyle->Red]
}
],
GraphicsSpacing->-.05]//Timing

ψ(x)

Values

Exp[Table[ChebyshevPsi[n],{n,20}]]

ChebyshevPsi2[n_]:=Plus@@(Floor[Log[#,n]]Log[#]&/@Prime[Range[PrimePi[n]]])

Exp[Table[ChebyshevPsi2[n],{n,20}]]

With[{n=20},Floor[Log[#,n]]Log[#]&/@Prime[Range[PrimePi[n]]]]

Plot

Show[GraphicsArray[
{
ListPlot[Table[ChebyshevPsi[n],{n,2,100}],Joined->True,PlotStyle->Red,AxesLabel->{x,ψ[x]}],
ListPlot[Table[ChebyshevPsi[n]-ChebyshevTheta[n],{n,2,1000}],PlotStyle->Red,AxesLabel->{x,ψ[x]-θ[x]},Joined->True]
}
],GraphicsSpacing->-.05]//Timing

Relation

ChebyshevPsi/@Range[10]//N

Table[Sum[ChebyshevTheta[x^(1/k)],{k,10}],{x,10}]//N

Simplify[Table[ChebyshevPsi[x]-Sum[ChebyshevTheta[x^(1/k)],{k,Floor[Log[2,x]]}],{x,500}]]//Union