Koch Antisnowflake

Author

Eric W. Weisstein
December 28, 2025

This notebook downloaded from https://mathworld.wolfram.com/notebooks/Fractals/KochAntisnowflake.nb.

For more information, see Eric's MathWorld entry https://mathworld.wolfram.com/KochAntisnowflake.html.

©2025 Wolfram Research, Inc. except for portions noted otherwise

Figure

<<MathWorld`Fractal`

Motif

GraphicsRow[FractalMotif[KochAntisnowflakeMotif]]

Curve

GraphicsRow[
Table[Graphics[KochAntisnowflake[n],PlotLabel->Row[{Style["n",Italic],"==",n}," "]],{n,0,3}],
BaseStyle->InsetBoxOptions->{BaseStyle->Directive[LightDarkSwitched@Black,14,FontFamily->"Times"]},
Dividers->All]

Filled

GraphicsRow[
Table[Graphics[Polygon@@KochAntisnowflake[n],PlotLabel->Row[{Style["n",Italic],"==",n}," "]],{n,0,3}],
BaseStyle->InsetBoxOptions->{BaseStyle->Directive[LightDarkSwitched@Black,14,FontFamily->"Times"]},
Dividers->All]

Graphics

KochCurve

KochAntiCurve[n_]:=KochCurve[n,{0,-60,120,-60}Degree]

GraphicsRow[Graphics/@Table[KochAntiCurve[n],{n,0,4}]]

Table[Graphics[GeometricTransformation[KochAntiCurve[i],{RotationTransform[Pi,{1/2,0}],RotationTransform[-Pi/3,{1,0}],RotationTransform[Pi/3,{0,0}]}]],{i,0,3}]

Properties

ArcLength of one segment

Table[Tally[KochAntisnowflake[n]/.Line[x_]:>FullSimplify[EuclideanDistance@@@Partition[x,2,1]]],{n,0,4}]

Table[{{((((1/3)))^n),3 (4^n)}},{n,0,4}]

ArcLength of one edge

seq=Table[ArcLength[KochAntisnowflake[n]],{n,0,4}]/3//FullSimplify

FindSequenceFunction[seq,n+1]

ArcLength

seq=Table[ArcLength[KochAntisnowflake[n]],{n,0,4}]//FullSimplify

FindSequenceFunction[seq,n+1]//FullSimplify

Area

seq=(4/(Sqrt[3]))Table[Area[Polygon@@KochAntisnowflake[n]],{n,0,5}]

FindSequenceFunction[seq,n+1]//FullSimplify

Table[(1/5) (2+3 ((4^n)/(9^n))),{n,0,5}]

Limit[(1/5) (2+3 ((4^n)/(9^n))),n->∞]

NN[n_]:=3 4^n
L[n_]:=1/3^n
l[n_]:=NN[n]L[n]

FullSimplify[A[n]/.RSolve[{A[n]==A[n-1]-NN[n]L[n]^2Δ/4,A[0]==Δ},A[n],n][[1,1]]]

Table[(1/5) (2+(3^(1-2 n)) (4^n)),{n,0,5}]

Limit[(1/5) (2+(3^(1-2 n)) (4^n)),n->∞]Δ

EdgeCount

seq=Table[Length[KochAntisnowflake[n][[1]]]-1,{n,0,4}]

FindSequenceFunction[seq,n+1]