Polar Coordinates

Author

Eric W. Weisstein
March 9, 2014

This notebook downloaded from http://mathworld.wolfram.com/notebooks/CoordinateGeometry/PolarCoordinates.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/PolarCoordinates.html.

©2014 Wolfram Research, Inc. except for portions noted otherwise

Initialization

hat[v_]:=OverHat[StyleForm[v,FontWeight->"Bold",FontSlant->"Plain"]];

TraditionalDisplay[g_]:=(g/.{Derivative[1][x_]:>Overscript[x,"."],
Derivative[2][x_]:>Overscript[x,".."]}/.f_[t]:>f)//TraditionalForm

Figures

Axes

Graphics[{
{Arrow[{{-1,0},{1,0}}],Arrow[{{0,-.2},{0,1}}]},
{Thickness[.01],Arrow[{{0,0},{-.5,.5}}]},{Dashing[.03],Line[{.8{-1,1},{-.5,.5}}]},
{Red,PointSize[.03],Point[{-.5,.5}]},
Arrow[.3Table[Through[{Cos,Sin}[3π/4  k/20]],{k,0,20}]],
Text[Style[Row[{" ","θ"," "}]],.21{1,1},Background->White],
Text[Style["r",Italic],{-.45,.35},Background->White]
}]

Rings

PolarPlot[0,{q,0,2π},PolarAxes->True]

Graphics[{
{Red,Table[Circle[{0,0},r],{r,1/4,1,1/4}]},
{Blue,Line[{-#,#}&/@Table[Through[{Cos,Sin}[π k/6]],{k,5}]]},
Thick,Line[1.05{{{-1,0},{1,0}},{{0,-1},{0,1}}}],
Table[Text[d Degree,1.1Through[{Cos,Sin}[d Degree]],Background->White],{d,0,330,30}],
PointSize[.04],Point[{0,0}]
},ImageSize->300]

Cartesian Basis

r[x_,y_]:=Sqrt[x[t]^2+y[t]^2]hat[r][t]

r[x,y]

(OverHat[r])

hat/@{x,y}.{x[t],y[t]}/Sqrt[Dot[{x[t],y[t]},{x[t],y[t]}]]//TraditionalDisplay

(OverDot[r])

r

Together/@Collect[Expand[D[r[x,y],t]], hat[r][t]]//TraditionalDisplay

(OverDot[(OverHat[r])])

Simplify[D[OverHat[StyleForm[#,FontWeight->"Bold",FontSlant->"Plain"]]&/@{x,y}.{x[t],y[t]}/Sqrt[Dot[{x[t],y[t]},{x[t],y[t]}]],t]]//TraditionalDisplay

Polar Coordinates

rvec=r[t]{Cos[θ[t]],Sin[θ[t]]};

(OverHat[r])

rhat=Simplify[#/Sqrt[#.#]&@D[rvec,r[t]]]

(OverHat[θ])

that=PowerExpand[Simplify[#/Sqrt[#.#]&@D[rvec,θ[t]]]]

(OverDot[r])

dr=D[rvec,t]

Simplify[hat[r] dr.rhat+hat[θ]dr.that]//TraditionalDisplay

(Overscript[r, ..])

dr2=D[rvec,{t,2}]

Simplify[hat[r] dr2.rhat+hat[θ]dr2.that]//TraditionalDisplay

(OverDot[(OverHat[r])])

Simplify[(hat[r]#.rhat+hat[θ]#.that)&[D[rhat,t]]]//TraditionalDisplay

(OverDot[(OverHat[θ])])

Simplify[(hat[r]#.rhat+hat[θ]#.that)&[D[that,t]]]//TraditionalDisplay