Gauss-Kuzmin-Wirsing Constant

Author

Eric W. Weisstein
November 9, 2008

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Constants/Gauss-Kuzmin-WirsingConstant.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/Gauss-Kuzmin-WirsingConstant.html.

©2008 Wolfram Research, Inc. except for portions noted otherwise

Additional Authors

Eigenvalue calculation by Keith M. Briggs
July 8, 2003
http://research.btexact.com/teralab/documents/wirsing.pdf

High-Precision Value

Calculated by K. Briggs

briggs=-0.3036630028987326585974481219015562331108773522536578951882454814672269952942469109843408119343636368110982722637106169384746148597458013160652653818182378791324461398964764297409504462937594904870297728772511058335175922044472408659119650778105589295791867147529256536425918441217842344920572552942691004065778800676732430364396401389692767134073782286711534915435462112848419717968;

Precision[briggs]

Calculation via Eigenvalue

Matrix

Unoptimized

M[n_]:=Table[((((-1))^j)/(j!(((-2))^k)))Sum[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2))),{i,0,k}],{j,0,n},{k,0,n}]

Optimized

m[i_,j_,prec_]:=m[i,j,prec]=N[(((-2))^i)Pochhammer[N[i+2,prec],j](Zeta[N[i+j+2,prec]]((2^(i+j+2))-1)-(2^(i+j+2))),prec]
M[n_,prec_]:=Table[((((-1))^j)/(j!(((-2))^k)))Sum[Binomial[k,i]m[i,j,prec],{i,0,k}],{j,0,n},{k,0,n}]

Attempt to do Sum Analytically

V6

Sum[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2))),{i,0,k}]

FullSimplify[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2)))]

FunctionExpand[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2)))]

FullSimplify[%]

V7

Sum[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2))),{i,0,k}]//Timing

V10

Sum[Binomial[k,i](((-2))^i)Pochhammer[i+2,j](Zeta[i+j+2]((2^(i+j+2))-1)-(2^(i+j+2))),{i,0,k}]//Timing

First Few Terms

FullSimplify[M[1]]//TraditionalForm

FullSimplify[M[2]]//MatrixForm

Eigenvalues

Off[N::"meprec"];

Briggs' uses 1300 bits of precision

2^(-1300.)

and an 800×800 matrix

n=50

m50=M[50,100];//Timing

{λ=Eigenvalues[m50][[2]],Precision[λ],λ-briggs}//Timing

f[λ_?NumericQ]:=Det[m50-IdentityMatrix[51]λ]

{λ=(l/.FindRoot[f[l]==0,{l,-.30,-.31},Method->Brent,WorkingPrecision->50,PrecisionGoal->30,AccuracyGoal->{Infinity,Infinity}]),Precision[λ],λ-briggs}//Timing

n=100

M[100,100] crashes v5.0.1

m100=M[100,200];//Timing

{λ=Eigenvalues[m100][[2]],Precision[λ],λ-briggs}//Timing

f[λ_?NumericQ]:=Det[m100-IdentityMatrix[101]λ]

{λ=(l/.FindRoot[f[l]==0,{l,-.30,-.31},Method->Brent,WorkingPrecision->100,PrecisionGoal->100,AccuracyGoal->{Infinity,Infinity}]),Precision[λ],λ-briggs}//Timing

n=150

Precision[m150=M[150,200]]//Timing

Precision[m150=M[150,400]]//Timing

{λ=Eigenvalues[m150][[2]],Precision[λ],λ-briggs}//Timing

f[λ_?NumericQ]:=Det[m150-IdentityMatrix[151]λ]

{λ=(l/.FindRoot[f[l]==0,{l,-.30,-.31},Method->Brent,WorkingPrecision->150,PrecisionGoal->100,AccuracyGoal->{Infinity,Infinity}]),Precision[λ],λ-briggs}//Timing

n=200

Precision[m200=M[200,400]]//Timing

{λ=Eigenvalues[m200][[2]],Precision[λ],λ-briggs}//Timing

f[λ_?NumericQ]:=(x=Timing[Det[m200-IdentityMatrix[201]SetPrecision[λ,250]]];Print[λ-briggs," ",x];x[[2]])

{λ=(l/.FindRoot[f[l]==0,{l,-.30,-.31},Method->Brent,WorkingPrecision->250,PrecisionGoal->200,AccuracyGoal->{Infinity,Infinity}]),Precision[λ],λ-briggs}//Timing

f[λ_?NumericQ]:=(x=Timing[Det[m200-IdentityMatrix[201]SetPrecision[λ,250]]];Print[λ-briggs," ",x];x[[2]] 10^200)

{λ=(l/.FindRoot[f[l]==0,Evaluate[{l,briggs-10^-70,briggs+10^-70}],
Method->Brent,WorkingPrecision->250,PrecisionGoal->200,AccuracyGoal->{Infinity,Infinity}]),
Precision[λ],λ-briggs}//Timing

n=250

Precision[m250=M[250,500]]//Timing

f[λ_?NumericQ]:=(x=Timing[Det[m250-IdentityMatrix[251]SetPrecision[λ,300]]];Print[λ," ",x];10^150 x[[2]])

{λ=(l/.FindRoot[f[l]==0,Evaluate[{l,briggs-10^-70,briggs+10^-70}],
Method->Brent,WorkingPrecision->200,PrecisionGoal->200,AccuracyGoal->{Infinity,Infinity}]),
Precision[λ],λ}//Timing

(λ250=-0.30366300289873265859744812190155623311087735225365789518824548146722699529424691098434081193436363681109827226371061693843489649793014318366688747619660359004124128824799520091841149289834883983215597)-briggs

Precision[λ250]

n=300

Precision[m300=M[300,700]]//Timing

f[λ_?NumericQ]:=(x=Timing[Det[m300-IdentityMatrix[301]SetPrecision[λ,350]]];Print[λ," ",x];x[[2]])

{λ=(l/.FindRoot[f[l]==0,Evaluate[{l,λ250-10^-70,λ250+10^-70}],
Method->Brent,WorkingPrecision->400,PrecisionGoal->350,AccuracyGoal->{Infinity,Infinity}]),
Precision[λ],λ}//Timing

-briggs+(λ300=-0.303663002898732658597448121901556233110877352253657895188245481467226995294246910984340811934363636811098272263710616938474614859745801316065265335574364841150503904306589758545073151489074286629025338868229788808901260647292614575171848109592380289716789413769784400224748623750649956481047834323931745171403334234710826914460958328926033466816370506457061329832335597135121920348808652629472061856851763899000815`400.)

Scott Hempfill

Sum[(-1/2+(k+x)^(-1))^r/(k+x)^2,{k,Infinity}]

f[r_,x_]:=Sum[(-1/2+(k+x)^(-1))^r/(k+x)^2,{k,Infinity}]
m[n_]:=Transpose[Table[Series[f[r,x],{x,1/2,n-1}][[3]],{r,0,n-1}]]
gkw[n_]:=N[Eigenvalues[N[m[n],2*n],2],n/2];

gkw[10]//Timing

gkw[15]//Timing