Catalan Minimal Surface

Author

Eric W. Weisstein
April 16, 2024

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Surfaces/CatalanMinimalSurface.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/CatalanMinimalSurface.html.

©2024 Wolfram Research, Inc. except for portions noted otherwise

Equation

Hyperbolic parametrization

surf=a{u-Sin[u]Cosh[v],1-Cos[u]Cosh[v],4 Sin[u/2]Sinh[v/2]};

surf^2

eqn=Thread[{x^2,y^2,z^2}==surf^2/.{Sin[u_/2]^2:>(1-Cos[u])/2,Sinh[v_/2]^2:>(Cosh[v]-1)/2}]

gbeqn=Join[Numerator[Together[Subtract@@@eqn]]/.{Cos[u]->c,Sin[u]->s,Cosh[v]->ch,Sinh[v]->sh},{c^2+s^2-1,ch^2-sh^2-1}]

GroebnerBasis[gbeqn,{x,y,z},{u,v,c,s,ch,sh}]

Solve[%[[1]]==0,z]//Collect[#,x]&

Trig parametrization

surf=a{Sin[2ϕ]-2ϕ+(1/2)(v^2)Cos[2ϕ],-Cos[2ϕ]-(1/2)(v^2)Cos[2ϕ],2v Sin[ϕ]}

eqn=TrigExpand[Thread[{x^2,y^2,z^2}==surf]]

gbeqn=Join[Numerator[Together[Subtract@@@eqn]]/.{Cos[ϕ]->c,Sin[ϕ]->s},{c^2+s^2-1}]

Factor@GroebnerBasis[gbeqn,{x,y,z},{ϕ,v,c,s}]

Plot

Block[{a=1},ParametricPlot3D[surf,{u,0,6π},{v,-2,2},Boxed->False,Axes->False,Method->{"ShrinkWrap"->True},PlotPoints->100,PlotStyle->Opacity[.8]]]

Properties

<<MathWorld`Surfaces`
<<MathWorld`CurvilinearCoordinates`

surf=a{u-Sin[u]Cosh[v],1-Cos[u]Cosh[v],4 Sin[u/2]Sinh[v/2]};

assum=a>0&&0≤u<2π&&v∈Reals;

AlgebraicEquation

Subtract@@(impl==0)

AreaElement

Entity["Surface","CatalanSurface"]["AreaElement"][a][u,v]

FullSimplify[AreaElement[surf,{u,v}],assum]

CartesianEquation

impl==0

Centroid

ChristoffelSymbolOfTheSecondKind

FullSimplify[ChristoffelSymbols[surf,{u,v}],assum]

ChristoffelSymbolOfTheSecondKindArfken

FullSimplify[ChristoffelSymbols2[surf,{u,v}],assum]

FirstFundamentalForm

{ℰ,ℱ,𝒢}=Simplify[FirstFundamentalForm[surf,{u,v}],assum]

GaussianCurvatue

FullSimplify[GaussianCurvature[surf,{u,v}],assum]

ImplicitGaussianCurvatue

FullSimplify[GaussianCurvature[impl,{x,y,z}],assum&&(x|y|z)∈Reals]

ImplicitMeanCurvature

FullSimplify[MeanCurvature[impl,{x,y,z}],assum&&(x|y|z)∈Reals]

InertiaTensor

MeanCurvature

FullSimplify[MeanCurvature[surf,{u,v}],assum]

MetricTensor

MetricTensor[surf,{u,v}]//FullSimplify

NormalVector

Assuming[assum,FullSimplify[NormalVector[surf,{u,v}]]]/.Abs[x_]^2:>x^2//FullSimplify

PrincipalCurvatures

FullSimplify[PrincipalCurvatures[surf,{u,v}],assum]

SecondFundamentalForm

{ℯ,𝒻,ℊ}=FullSimplify[SecondFundamentalForm[surf,{u,v}],assum]

SurfaceArea

{ℰ,ℱ,𝒢}=Simplify[FirstFundamentalForm[surf,{u,v}]]

FullSimplify[(Sqrt[ℰ 𝒢-(ℱ^2)]),assum]

VectorLength

Assuming[assum,FullSimplify[Norm[surf]]]/.Abs[x_]^2:>x^2//FullSimplify

Volume