Cross Polytope

Author

Eric W. Weisstein
June 12, 2019

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Polytopes/CrossPolytope.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/CrossPolytope.html.

©2019 Wolfram Research, Inc. except for portions noted otherwise

Vertices

(* section 13.4 of Coxeter's Regular Polytopes *)
CrossPolytopeCoordinates[n_]:=Module[{a,r,k},a=Table[Flatten[Table[Through[{Cos,Sin}[(2 r-1) Pi k/n]],{r,Floor[n/2]}]],{k,2 n}];
If[OddQ[n],Table[Join[a[[k]],{(-1)^k/Sqrt[2]}],{k,2 n}],a]/Sqrt[n]
]

TextGrid[Table[{n,CrossPolytopeCoordinates[n]},{n,4}],Dividers->All]

EdgeLength

Table[EuclideanDistance@@@Subsets[CrossPolytopeCoordinates[n],{2}]//FullSimplify//Union,{n,2,5}]

Region

ConvexHullMesh[CrossPolytopeCoordinates[3]]

RegionPlot3D[Norm[{x,y,z},1]≤1,{x,-1,1},{y,-1,1},{z,-1,1}]

Content

RegionMeasure[ConvexHullMesh[CrossPolytopeCoordinates[3]]]

ConvexHullMesh[CrossPolytopeCoordinates[3]]//InputForm

(1/((((Sqrt[2])))^2))Integrate[Boole[Norm[{x,y},1]≤1],{x,y}∈FullRegion[2]]//Timing

PolyhedronData["Octahedron","Volume"]

(1/((((Sqrt[2])))^3))Integrate[Boole[Norm[{x,y,z},1]≤1],{x,y,z}∈FullRegion[3]]//Timing

RegionMeasure[Octahedron[]]

Norm[{x,y,z,w},1]

(1/((((Sqrt[2])))^4))Integrate[Boole[Norm[{x,y,z,w},1]≤1],{x,y,z,w}∈FullRegion[4]]//Timing

Table[((2^n)/((2^(n/2))n!)),{n,10}]

Graph

Table[With[{v=CrossPolytopeCoordinates[n]},Graph[UndirectedEdge@@@Select[Subsets[Range[2n],{2}],EuclideanDistance@@v[[#]]==1.&]]],{n,2,6}]

RecognizeGraph/@%