Recurrence Plot

Author

Eric W. Weisstein
April 16, 2005

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Graphics/RecurrencePlot.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/RecurrencePlot.html.

©2005 Wolfram Research, Inc. except for portions noted otherwise

Initialization

<<Utilities`Typesetting`

Recurrence Plot

Timing[soln=With[{r=28,σ=10,b=8/3},NDSolve[{
x'[t]==σ (y[t]-x[t]),
y'[t]==-x[t]z[t]+r x[t]-y[t],
z'[t]==x[t] y[t]-b z[t],
x[0]==1,
y[0]==0,
z[0]==0
},{x,y,z},{t,0,25},MaxSteps->5000]]]

g1=ParametricPlot3D[Evaluate[{x[t],y[t],z[t],Red}/.soln],{t,0,20},PlotPoints->1000,PlotRange->All]

solnt[t_]:=Evaluate[{x[t],y[t],z[t]}/.soln][[1]]

(g2=With[{ϵ=5},
ListDensityPlot[Table[1-UnitStep[ϵ-Norm[solnt[t]-solnt[τ]]],
{t,0,25,.1},{τ,0,25,.1}],Mesh->False,MeshRange->{{0,25},{0,25}},FrameLabel->TraditionalForm/@{t,τ}
]])//Timing

Show[GraphicsArray[{g1,g2}],ImageSize->500]

Global Recurrence Plots

Show[GraphicsArray[Partition[ContourPlot[Evaluate[Abs[Subtract@@(#/@{t,τ})]],{t,-10,10},
{τ,-10,10},ColorFunction->Hue,
FrameLabel->TraditionalForm/@{t,τ},
PlotLabel->TraditionalForm[#[z]],
DisplayFunction->Identity,
ContourLines->False,PlotPoints->200]&/@{Sin,Tan,Sec,Log,Sqrt,#^2&},3]
],GraphicsSpacing->{-.05,0}]