Star of David Theorem

Author

Eric W. Weisstein
March 25, 2009

This notebook downloaded from http://mathworld.wolfram.com/notebooks/Combinatorics/StarofDavidTheorem.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/StarofDavidTheorem.html.

©2009 Wolfram Research, Inc. except for portions noted otherwise

First Theorem

And@@And@@@Table[Equal@@GCD@@@Partition[Binomial@@@{
{n-1,k},{n,k-1},{n+1,k+1},
{n-1,k-1},{n,k+1},{n+1,k}
},3],{n,0,10},{k,0,n}]

And@@And@@@Table[Equal@@GCD@@@Map[Binomial@@#&,{
{{n-1,k},{n,k-1},{n+1,k+1}},
{{n-1,k-1},{n,k+1},{n+1,k}},
{{n-1,k-2},{n-1,k-1},{n-1,k},{n-1,k+1}}
},{2}],{n,0,10},{k,0,n}]

And@@And@@@Table[Equal@@GCD@@@Map[Binomial@@#&,{
{{n,k+2},{n-1,k},{n-2,k-2},{n,k-1},{n+2,k},{n+1,k+1}},
{{n-2,k},{n-1,k-1},{n,k-2},{n+1,k},{n+2,k+2},{n,k+1}},
{n-2,k-5+#}&/@Range[7]
},{2}],{n,0,10},{k,0,n}]

Second Theorem

Figure

ClosedLine[l_List]:=Line[Append[l,l[[1]]]]

Show[Graphics[{
Text[Sequence@@#,FormatType->TraditionalForm]&/@Transpose[{Binomial@@#&/@{{n,k+1},{n-1,k},{n-1,k-1},{n,k-1},{n+1,k},{n+1,k+1}},t=Through[{Cos,Sin}[π #/3]]&/@Range[0,5]}],
Text[Binomial[n,k],{0,0},FormatType->TraditionalForm],
Transpose[{{Red,Blue},ClosedLine/@Transpose[Partition[1.5t,2]]}]
}
],AspectRatio->Automatic,PlotRange->All]

Binomial

id=Times@@@Map[Binomial@@#&,{{{n-1,k-1},{n+1,k},{n,k+1}},{{n-1,k},{n,k-1},{n+1,k+1}}},{2}]

Equal@@FunctionExpand[id]

FunctionExpand[id][[1]]/.Gamma[x_]:>(x-1)!//TraditionalForm

q-Binomial

id=Times@@@Map[QBinomial[Sequence@@#,q]&,{{{n-1,k-1},{n+1,k},{n,k+1}},{{n-1,k},{n,k-1},{n+1,k+1}}},{2}]

Equal@@FunctionExpand[id]

FunctionExpand[id][[1]]/.Gamma[x_]:>(x-1)!//TraditionalForm