Chebyshev Polynomial of the First Kind

Author

Eric W. Weisstein
November 8, 2021

This notebook downloaded from http://mathworld.wolfram.com/notebooks/SpecialFunctions/ChebyshevPolynomialoftheFirstKind.nb.

For more information, see Eric's MathWorld entry http://mathworld.wolfram.com/ChebyshevPolynomialoftheFirstKind.html.

©2021 Wolfram Research, Inc. except for portions noted otherwise

Enumeration

poly=ChebyshevT;

poly[#,x]&/@Range[0,10]//ColumnForm//TraditionalForm

DeleteCases[CoefficientList[poly[#,x],x],0]&/@Range[0,10]

Flatten[%]

Other Definitions

Table[ChebyshevT[n,x],{n,0,9}]//Column//TraditionalForm

Cos

cos(n (cos^(-1))(x))

Table[Cos[n ArcCos[z]],{n,0,9}]//FunctionExpand//Column//TraditionalForm

Table[ChebyshevT[n,z]-Cos[n ArcCos[z]]/.{z->RandomComplex[(I+1){-5,5}],n->RandomReal[{-10,10}]},{1000}]//Chop//Union

Cosh

pers. comm., Nov 8, 2021

cosh(n (cosh^(-1))(z))

Table[Cosh[n ArcCosh[z]],{n,0,9}]//FunctionExpand//Column//TraditionalForm

FullSimplify[Subtract@@{Cosh[n ArcCosh[x]],ChebyshevT[n,x]},n∈Integers]

FullSimplify[FunctionExpand[%],n∈Integers]

Table[ChebyshevT[n,x]-Cosh[n ArcCosh[x]]/.{x->RandomComplex[(I+1){-5,5}],n->RandomReal[{-10,10}]},{1000}]//Chop//Union

Silverman

(1/2) (((((Sqrt[(x^2)-1])+x))^(-n))+((((Sqrt[(x^2)-1])+x))^n))

Table[(((x+Sqrt[x^2-1])^n+(x+Sqrt[x^2-1])^(-n)))/2,{n,0,9}]//Expand//FullSimplify//Expand//Column//TraditionalForm

Plot3D[ChebyshevT[n,x]-(1/2) ((((x+(Sqrt[(x^2)-1])))^n)+(((x+(Sqrt[(x^2)-1])))^(-n))),{n,-5,5},{x,-10,10},WorkingPrecision->#1]&/@{MachinePrecision,20}

Table[ChebyshevT[n,x]-((x+Sqrt[x^2-1])^n+(x+Sqrt[x^2-1])^(-n))/2/.{x->RandomComplex[(I+1){-5,5},WorkingPrecision->50],n->RandomReal[{-10,10},WorkingPrecision->50]},{1000}]//Chop//Union

Functions [only true for integer n]

http://functions.wolfram.com/05.04.27.0009.01

((z^n)/2) (((((Sqrt[1-(1/(z^2))])+1))^n)+(((1-(Sqrt[1-(1/(z^2))])))^n))

Table[z^n ((1+Sqrt[1-1/z^2])^n+(1-Sqrt[1-1/z^2])^n)/2,{n,0,9}]//FullSimplify//Expand//Column//TraditionalForm

Plot3D[ChebyshevT[n,x]-(1/2) (x^n) ((((1-(Sqrt[1-(1/(x^2))])))^n)+(((1+(Sqrt[1-(1/(x^2))])))^n)),{n,-5,5},{x,-5,5},WorkingPrecision->#1]&/@{MachinePrecision,20}

Table[ChebyshevT[n,x]-(1/2) (x^n) ((((1-(Sqrt[1-(1/(x^2))])))^n)+(((1+(Sqrt[1-(1/(x^2))])))^n))/.{x->RandomComplex[(I+1){-5,5},WorkingPrecision->50],n->RandomInteger[{-10,10}]},{100}]//Chop//Union

Table[{x,n,ChebyshevT[n,x]-(1/2) (x^n) ((((1-(Sqrt[1-(1/(x^2))])))^n)+(((1+(Sqrt[1-(1/(x^2))])))^n))}/.{x->RandomComplex[(I+1){-5,5},WorkingPrecision->MachinePrecision],n->RandomReal[{-10,10},WorkingPrecision->MachinePrecision]},{2}]

N[ChebyshevT[n,z]-(1/2) (z^n) ((((1-(Sqrt[1-(1/(z^2))])))^n)+(((1+(Sqrt[1-(1/(z^2))])))^n))/.{z->-2-I,n->-1/10},20]

Plot

Plot[Evaluate[Table[ChebyshevT[n,x],{n,5}]],{x,-1,1},PlotStyle->{Red,Yellow,Green,Blue,Violet}]

Michael's Plot

V5

Show[Graphics[Reverse[MapIndexed[Function[{li,pos},(*black or white*){GrayLevel[If[EvenQ[pos[[1]]],1,0]],Polygon@@(*wrap line around a circle*)Map[N[(2 pos[[1]]+#[[2]])*{Cos[Pi #[[1]]],Sin[#[[1]] Pi]}]&,li,{-2}]}],(*use Plot to make function graphs*)Flatten[(Function[chebys,Plot[chebys,{x,-1,1},PlotPoints->200,DisplayFunction->Identity],{HoldAll}]@@((*avoid evaluation to explicit polynomials*)Apply[List,Hold@@{Join@@MapIndexed[#//.C->2 #2[[1]]-2&,(*the ChebyshevT to be displayed*)Table[Hold[ChebyshevT[C,x]],{C,0,52,2}]]},{1}]))[[1]]],{1}]]],PlotRange->All,AspectRatio->Automatic];

Definition

(Subscript[T, n])(cos(θ))=cos(n θ)

Subtract@@@Table[{ChebyshevT[n,Cos[θ]],Cos[n θ]},{n,-10,10}]//Simplify

Subtract@@@Table[{ChebyshevT[n,Cosh[θ]],Cosh[n θ]},{n,-10,10}]//Simplify

Sums

(∑_(n=0)^∞)(t^n) (Subscript[T, n])(x)==((1-t x)/((t^2)-2 t x+1))

Sum[ChebyshevT[n,x](t^n),{n,0,∞}]

Simplify[%]

Series[%,{t,0,5}]

SeriesCoefficient[((1-t x)/(1+(t^2)-2 t x)),{t,0,n}]//InputForm

FullSimplify[%]//InputForm

GeneratingFunction[ChebyshevT[n,x],n,t]

2 (∑_n^∞)(t^n) (Subscript[T, n])(x)+(Subscript[T, 0])(x)==((1-(t^2))/((t^2)-2 t x+1))

ChebyshevT[0,x]+2Sum[ChebyshevT[n,x](t^n),{n,∞}]

(1/2) n (∑_(r=0)^(⌊n/2⌋))((((-1))^r)/(n-r)) (Binomial[n-r, r]) (((2 x))^(n-2 r))==(Subscript[T, n])(x)

(n/2)Sum[((((-1))^r)/(n-r))Binomial[n-r,r](((2x))^(n-2r)),{r,0,Floor[n/2]}]

(∑_(m=0)^(⌊n/2⌋))((((x^2)-1))^m) (Binomial[n, 2 m]) (x^(n-2 m))==(Subscript[T, n])(x)

Sum[Binomial[n,2m](x^(n-2m))((((x^2)-1))^m),{m,0,Floor[n/2]}]

FullSimplify[%]

Products

(2^(n-1)) (∏_k^n)(x-cos(((π (2 k-1))/(2 n))))==(Subscript[T, n])(x)

(2^(n-1))Product[x-Cos[(((2k-1)π)/(2n))],{k,n}]

Table[(2^(n-1))Product[x-Cos[(((2k-1)π)/(2n))],{k,n}],{n,5}]//Expand//FunctionExpand//Expand

Recurrence Relations

(Subscript[T, n])(x)==2 x (Subscript[T, n-1])(x)-(Subscript[T, n-2])(x)

V6

RSolve[{ChebyshevT[n,x]==2x ChebyshevT[n-1,x]-ChebyshevT[n-2,x],T[0,x]==1,T[1,x]==x},T[n,x],n]

V7

RSolve[{ChebyshevT[n,x]==2x ChebyshevT[n-1,x]-ChebyshevT[n-2,x],T[0,x]==1,T[1,x]==x},T[n,x],n]

RSolve[{T[n]==2x T[n-1]-T[n-2],T[0]==1,T[1]==x},T[n],n]

FullSimplify[%,n∈Integers&&n>0]

T(n+1)==x T(n)-(Sqrt[(1-(x^2)) (1-((T(n))^2))])

RSolve[{T[n+1]==x T[n]-Sqrt[(1-x^2)(1-T[n]^2)],T[0]==1,T[1]==x},T[n],n]

(x-1) (T(2 n+1)-1)==(((T(n+1)-T(n)))^2)

RSolve[{(x-1)(T[2n+1]-1)==(T[n+1]-T[n])^2,T[0]==1,T[1]==x},T[n],n]

2 ((x^2)-1) (T(2 n)-1)==(((T(n+1)-T(n-1)))^2)

RSolve[{2(x^2-1)(T[2n]-1)==(T[n+1]-T[n-1])^2,T[0]==1,T[1]==x},T[n],n]

Determinant Identity

chebTDet[n_,x_]:=Module[{i,c=2x IdentityMatrix[n]},
Do[
c[[i,i+1]]=c[[i+1,i]]=1,
{i,n-1}];
c[[1,1]]=x;
c
]

chebTProd[n_,x_]:=Product[2(x-Cos[(2k-1) Pi/2/n]),{k,n}]/2

chebTDet[5,x]//MatrixForm

Det/@Table[chebTDet[n,x],{n,5}]

Expand[Table[chebTProd[n,x],{n,5}]]

Table[ChebyshevT[n,x],{n,5}]

Approximations of powers

p[n_,x_]:=x^n-2^(1-n)ChebyshevT[n,x]

Simplify[Table[p[n,x],{n,5}]]

Show[GraphicsArray[Partition[Table[Plot[{p[n,x],x^n},{x,0,1},PlotRange->All,DisplayFunction->Identity],{n,6}],3]]]